Chitarra
La Costruzione del Corpo d'una Chitarra.

Oggetti:    prism.
Metodi: cubic_spline, .

La Costruzione dettagliata:

La forma di base d'un corpo di una chitarra si puede fare con un prisma (generalizzato anche con una superficie di base limitato di una curva!), se si prende un manto formato da una curva spline cubica.
Per la definizione di un prisma adatto abiamo bisogno di una serie di punti d'appoggio, che sono posto sulla linea della silhouette del corpo della chitarra. Mettere alla positione giusta questi punti è una cosa molto delicata. Questo è una situazione giusta per mettere in gioco il metodo di "trial and error", vuole dire: bisogno di provare!
Quando faciamo la construzione del corpo della chitarra nel piano xy, il corpo è simmetrio al piano yz . I punti simmetrico si può fare molto facile con la definizione di variabili, dove le coordinate dei punti riflessi dipendono dalle coordinate dei punti originali.

// ----------- Dimensioni
#declare G_z = 0.15;// Spessore
// Siluetta al lato destra:
// ---- valori <x,y> -----
#local S0 = < 0.00, 0.00>;
#local S1 = < 0.16, 0.05>;
#local S2 = < 0.22, 0.20>;
#local S3 = < 0.15, 0.35>;
#local S4 = < 0.17, 0.48>;
#local S5 = < 0.12, 0.56>;
#local S6 = < 0.00, 0.60>;
// Vettori 2 dimsionale: S(u,v).
// Qui: Quando S =  S(Xs,Yx),
// poi S.u=Xs u. X.v=Ys.

// Immagine riflessa automatica
// Siluetta al lato sinistra:
#local S7 = <-S5.u, S5.v>;
#local S8 = <-S4.u, S4.v>;
#local S9 = <-S3.u, S3.v>;
#local S10 = <-S2.u, S2.v>;
#local S11 = <-S1.u, S1.v>;
//--------------------------
// Prisma lineare direzione y:
prism {
   linear_sweep
   cubic_spline
   G_z, 0.00, 15

   S0, S1, S2, S3, S4,
   S5, S6, S7, S8, S9,
   S10, S11,
   S0, // l'ultimo = il primo
   S1, // 2 di più!!!
   S2
   texture { /*come vuole!*/}
   rotate<-90,0,0>
   //gira il prisma in piano xy!!!
   translate<0.0,0,0>
} // fine del prisma ------------

Il corpo della chitarra: I punti d'appoggio della linea siluetta sono rappresenti con sfere picole. I punti simmetrici di S7 a S11 sono verde.

Cliccare qui per una descrizione completa
di questa scena in POV-Ray:
"guitar.txt" o "guitar.pov"

Quando si definisce il prisma in alto con nome di "Body_Shape", si può creare con questo corpo di base il corpo della chitarra.
Colori ("texture") differenti per la facciata / il rovescio e alle superficie laterale si può avere, se si addiziona più volte la stessa forma di base solo proporzionata un poco differente. Si può fare questo così, che la forma del corpo primo solo si fa vedere alla facciata e l'altro corpo si lascia vedere solo con superficie laterale. Poi possiamo sottrarre di questo corpo l'interno e un cilindro per l'apertura rotondo nella chitarra.

L'esempio qui vuole dimostrare questo:

//---- il corpo della chitarra
difference{
union { // le parti positive
 object{Body_Shape
   scale< 1.010,1.010,  0.95>
   translate<0,-0.005*G_y, -0.05*G_z/2>
   texture{G_Texture_outside1} }
object{Body_Shape
   texture{G_Texture_outside  } }
}// fine del "union"
 // delle parte positive del corpo

// scavare l'interno
object{Body_Shape
  scale<0.99,0.99,1-0.01*(1/G_z)>
  translate<0,0.005,-0.005>
  texture{ G_Texture_inside}}
// das Loch
cylinder { <0,0,-0.1>,<0,0,0.1>,G_Hole_R
  translate<0,G_Hole_y,-G_z>
  texture{G_Texture_outside}
  } // fine del cilindro  -----------
}// fine della differenza  ------------
// -- fine del corpo della chitarra

Cliccare qui per una descrizione completa
di questa scena in POV-Ray:
"guitar.txt" o "guitar.pov"