Descriptions et exemples pour le POV-Ray raytracer par Friedrich A. Lohmueller
      Objets POV-Ray - Comment faire des objets pour POV-Ray
 English English English
Italiano  Italiano
Deutsch 
Page d'Accueil
- POV-Ray Tutorial

  - Exemples POV-Ray
   Table des matières
  - Géométrie
  - Architecture
    - Maison
    - Toit
    - Tour
    - Châteaux
    - Fenêtre + Porte
        - Fenêtre
        - Porte
        - Shoji
        - Paravent
    - Escaliers
    - Pyramide
    - Colonne
    - Arc, Arche
    - Clôtures
    - Meubles
    - Ménage
  - Technique
                                       
 
Porte

Porte comme "macro"

Objets:   "box", "sphere", "cylinder".
Méthodes: "difference", "union", "#declare", "macro".
La Constuction dans tous les détails:
La porte est construit de manière ressemblant à "Fenêtre". Cela est fait comme "macro" pour laisser le angle de ouverture de la porte libre à choisir.
 
Un ficher include pour utiliser cet objet comme un objet prêt à l'usage vous pouvez trouver sur mon site Objets POV-Ray. 
//-----------------------------------------
#macro Door (Door_Angle) //----------------
union{  // I
 difference{
  box{<-0.50,0.01,-0.02>,< 0.50,1.80,0.02>}
  box{<-0.45,0.85,-0.03>,<-0.03,1.27,0.03>}
  box{< 0.03,0.85,-0.03>,< 0.45,1.27,0.03>}
  box{<-0.45,1.33,-0.03>,<-0.03,1.75,0.03>}
  box{< 0.03,1.33,-0.03>,< 0.45,1.75,0.03>}
  texture{Door_Texture_1}
  } // ---end of difference
 box{ <-0.49,0.81,0>,< 0.49,1.79,0.001>
      texture{T_Glass3}}  // no interior!!!
 // door handle
 union{ // II
  sphere  {<-0.15,0,-0.07>, 0.015 }
  cylinder{<-0.15,0,-0.07>,<0,0,-0.1>,0.015}
  sphere  {< 0,0,-0.07>, 0.015}
  cylinder{< 0,0,-0.07 >,<0,0,0>,0.015}
  cylinder{< 0,0,-0.035>,<0,0,0>,0.04}
  texture { Chrome_Metal }
  translate<0.43,0.75,0>
  }// end of union II

 // rotation of the door:
 translate< 0.50,0,0>
 rotate<0,-Door_Angle,0>
 translate<-0.50,0,0>
 } // ---end of union I
#end // ----------- end of Door(...) macro
//-----------------------------------------

#declare Door_Hole =   //symmetric!!!
  box{<-0.50,0.01,-0.50>,< 0.50,1.80,0.50>
      texture{Wall_Texture_2}}
//--------- end of Door_Hole --------------
Une porte avec fenêtre e poignée.
 
Pour metter les portes aux positions, on doit premierment definir les posizions avec des variables. Puis on peut soustraire aussi baie de porte du mur et mouvoir les portes aux positions. 

#declare Door_Positon_1 = <-1,0,0>;
#declare Door_Positon_1 = < 1,0,0>;

difference{
box   { <-2,0,0>,< 2,2.3,0.2>
        texture {Wall_Texture_1}}
object{ Door_Hole translate Door_Positon_a}
object{ Door_Hole translate Door_Positon_b}
} // end of difference --------------------

object{ Door(85) translate Door_Positon_1}
object{ Door(25) scale<-1,1,1>
                 translate Door_Positon_2}
//-----------------------------------------
Cela fait l'image suivante:
Porta
Cliquez ici pour un description complète de la scène
pour POV-Ray: fichier ".txt" ou fichier ".pov"
Objets prêt à l'usage pour POV-Ray comme
fichiers include avec fichiers exemple
on peut trouver sur la POV-Ray Objects page.
top
© Friedrich A. Lohmüller, 2012
www.f-lohmueller.de