Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
Esempi POV-Ray - Come fare oggetti per POV-Ray
 English English English
Français français
Deutsch Deutsch
Home
- POV-Ray Tutorial

  - Esempi per POV-Ray
   Indice generale
  - Geometria
  - Architettura
    - Casa
    - Tetto
    - Torre
    - Castello
    - Finestra e Porta
      - Finestra
      - Porta
      - Shoji
      - Paravent
    - Scale
    - Piramide
    - Colonna
    - Arco
    - Recinti
    - Mobili
    - Faccende di Casa
  - Tecnica
                                       
 
Porta

Porta come "macro"

Oggetti: "box", "sphere", "cylinder".
Metodi: "difference", "union", "#declare", "macro".
La costruzione nel dettaglio:
La porta é realizzato in un modo simile alla "Finestra". Questo é fatto come "macro" per lasciare scegliere libero il angolo d'apertura della porta.
 
Un file include per usare questo oggetto come un oggetto pronto per l'uso si trova su la mia paggina Oggetti POV-Ray. 
//-----------------------------------------
#macro Door (Door_Angle) //----------------
union{  // I
 difference{
  box{<-0.50,0.01,-0.02>,< 0.50,1.80,0.02>}
  box{<-0.45,0.85,-0.03>,<-0.03,1.27,0.03>}
  box{< 0.03,0.85,-0.03>,< 0.45,1.27,0.03>}
  box{<-0.45,1.33,-0.03>,<-0.03,1.75,0.03>}
  box{< 0.03,1.33,-0.03>,< 0.45,1.75,0.03>}
  texture{Door_Texture_1}
  } // ---end of difference
 box{ <-0.49,0.81,0>,< 0.49,1.79,0.001>
      texture{T_Glass3}}  // no interior!!!
 // door handle
 union{ // II
  sphere  {<-0.15,0,-0.07>, 0.015 }
  cylinder{<-0.15,0,-0.07>,<0,0,-0.1>,0.015}
  sphere  {< 0,0,-0.07>, 0.015}
  cylinder{< 0,0,-0.07 >,<0,0,0>,0.015}
  cylinder{< 0,0,-0.035>,<0,0,0>,0.04}
  texture { Chrome_Metal }
  translate<0.43,0.75,0>
  }// end of union II

 // rotation of the door:
 translate< 0.50,0,0>
 rotate<0,-Door_Angle,0>
 translate<-0.50,0,0>
 } // ---end of union I
#end // ----------- end of Door(...) macro
//-----------------------------------------

#declare Door_Hole =   //symmetric!!!
  box{<-0.50,0.01,-0.50>,< 0.50,1.80,0.50>
      texture{Wall_Texture_2}}
//--------- end of Door_Hole --------------
Una porta con finestra e maniglia.
 
Per mettere le porte alle sue posizioni, dobbiamo primo definire le posizioni con variabili. Poi si può sottrarre anche il vano per le porte del muro e muovere le porte alle sue posizioni. 

#declare Door_Positon_1 = <-1,0,0>;
#declare Door_Positon_1 = < 1,0,0>;

difference{
box   { <-2,0,0>,< 2,2.3,0.2>
        texture {Wall_Texture_1}}
object{ Door_Hole translate Door_Positon_a}
object{ Door_Hole translate Door_Positon_b}
} // end of difference --------------------

object{ Door(85) translate Door_Positon_1}
object{ Door(25) scale<-1,1,1>
                 translate Door_Positon_2}
//-----------------------------------------
Questo fa l'imagine seguente:
Porta
Cliccare qui per una descrizione completa della scèna
per POV-Ray: ".txt" file ou ".pov" file
Oggetti pronto per l'uso per POV-Ray
come Archivi include con archivi esempio
si trova su la Paggina POV-Ray Objects.
top
© Friedrich A. Lohmüller, 2006
www.f-lohmueller.de