La Construction détaillée :
1. Un arc est la difference d'un "box" et d'un "cylinder" :
Evitez des surfaces coïncidentes !!!!
//-------------------- arch -------------------------
#declare Arch = difference{
box {<-1.1,0,-0.1>,< 1.1,1.1,0.1>}
cylinder {<0,0,-0.11>,<0,0,0.11>,0.9 }
texture{pigment{color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//--------------------------------------------------
2. Une colonne acec un cône et des anneaux (tore) aux fins :
//------------- Pfeiler (pillar) --------------------
#declare Pillar = union{
torus{0.10,0.05 translate<0,1.45,0>}
torus{0.12,0.05 translate<0,0.04,0>}
cone {<0,0,0>,0.12,<0,1.5,0>,0.1}
texture{pigment{color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//---------------------------------------------------
3. Quatre arcs placés sur 4 colonnes e puis relevés
sur une pyramide des escaliers.
#declare Arches =
union{// --------arch upon columns -------------------
object{Pillar translate<-1,0,-1>}
object{Pillar translate< 1,0,-1>}
object{Pillar translate<-1,0, 1>}
object{Pillar translate< 1,0, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5,-1>}
object{Arch rotate<0,90,0> translate< 1,1.5, 0>}
object{Arch rotate<0,90,0> translate<-1,1.5, 0>}
} // -------------------------------------------------
#declare Steps =
union{ // -------------------- stairs ----------------
box{<-1.20,0.30,-1.20>,<1.20,0.45,1.20>}
box{<-1.50,0.15,-1.50>,<1.50,0.30,1.50>}
box{<-1.80,0.00,-1.80>,<1.80,0.15,1.80>}
texture{T_Stone8 scale 0.3 pigment{quick_color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//--------------------- end of the stairs-----------
Et finalement:
4. Tous ensemble combiné avec "union"
pour être transformé librement :
// -------- Tous ensemble -----------
union{object{Arches translate<0,0.45,0>}
object{Steps}
scale <1,1,1>
rotate<0,0,0>
translate<0,0,0>
}// end of union
//---------------------------------- end
|
|
Cliquez ici pour un description de la scène
pour POV-Ray :
"povarc4.txt" ou
"povarc4.pov"
|
