La costruzione nel dettaglio:
1. Un Arco é una "difference" di "box" e di "cylinder":
Evitare assolutamente superfici coincidentes!!
//-------------------- arco -------------------------
#declare Arch = difference{
box {<-1.1,0,-0.1>,< 1.1,1.1,0.1>}
cylinder {<0,0,-0.11>,<0,0,0.11>,0.9 }
texture{pigment{color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//--------------------------------------------------
2. Una colonna con un cono e anelli (torus) alle fini:
//------------- colonna ------------------------
#declare Pillar = union{
torus{0.10,0.05 translate<0,1.45,0>}
torus{0.12,0.05 translate<0,0.04,0>}
cone {<0,0,0>,0.12,<0,1.5,0>,0.1}
texture{pigment{color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//---------------------------------------------------
3. Quattro archi piazzati su quatto colonne e poi sollevare su una
una piramide di scale.
#declare Arches =
union{// -------- arci sulle colonne -----------------
object{Pillar translate<-1,0,-1>}
object{Pillar translate< 1,0,-1>}
object{Pillar translate<-1,0, 1>}
object{Pillar translate< 1,0, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5,-1>}
object{Arch rotate<0,90,0> translate< 1,1.5, 0>}
object{Arch rotate<0,90,0> translate<-1,1.5, 0>}
} // -------------------------------------------------
#declare Steps =
union{ // -------------------- scale ----------------
box{<-1.20,0.30,-1.20>,<1.20,0.45,1.20>}
box{<-1.50,0.15,-1.50>,<1.50,0.30,1.50>}
box{<-1.80,0.00,-1.80>,<1.80,0.15,1.80>}
texture{T_Stone8 scale 0.3 pigment{quick_color White}
normal {bumps 0.4 scale 0.007}
finish {diffuse 0.9 phong 1}}
}//--------------------- end of the stairs-----------
4. Tutto insieme in una "union" per essere trasformato liberamente:
// -------- tutto insieme --------------
union{object{Arches translate<0,0.45,0>}
object{Steps}
scale <1,1,1>
rotate<0,0,0>
translate<0,0,0>
}// end of union
//---------------------------------- end
|
|
|
