Camion - 1. Ruote e Chassis

//------------------------ object Wheel
#declare Wheel =          // Ruota
union{
 intersection{
  torus{ 0.35,0.15  rotate<90,0,0> }
  cylinder{ <0,0,-0.20>,<0,0,0.2>,0.47}

  texture{ pigment{ color rgb<1,1,1>*0.15}
           normal { bumps .5 scale .005}
           finish { diffuse .9 phong .2}
         } // end of texture
 }// end intersection
 sphere{ <0,0,0>,0.45
         scale<1,1,0.25>
         texture {
           Chrome_Metal
           normal{ bumps 0.5 scale 0.005}
           finish{ diffuse 0.9 phong 0.5}
         } // end of texture
 } // end of sphere ---------------------

translate<0,0.45,0>
} // end of union --------- end of Wheel
//---------------------------------------
object{ Wheel translate<0,0,0>}
//---------------------------------------

#declare Half = 1.00;
// = mezzo scartamento
#declare Axis_Distance = 3.50;
#declare Wheel_Angle = 30;

#declare Wheel_D= //-------  Ruota doppia
union{
object{ Wheel translate<0,0,-0.15>}
object{ Wheel translate<0,0, 0.15>}
} //--------------------------------------

#declare Double_Axes = //----- Asse doppio
union{
object{ Wheel_D translate<-0.6,0,-Half>}
object{ Wheel_D translate<-0.6,0, Half>}
object{ Wheel_D translate<+0.6,0,-Half>}
object{ Wheel_D translate< 0.6,0, Half>}
} //--------------------------------------

#macro Chassis (Front_Wheel___Angle)
//------------------------------ Chassis
union{
object{ Wheel
        rotate<0,Front_Wheel___Angle,0>
        translate< 0,0,-Half>}
object{ Wheel
        rotate<0,Front_Wheel___Angle,0>
        translate< 0.00,0, Half>}
object{ Double_Axes
        translate<-Axis_Distance,0,0>}
object{
 Round_Box(<-Axis_Distance-1,0,-0.5>,
           <0.25,0.50, 0.5>, 0.025, 0)
 texture{ pigment{ color rgb 0.2}
          finish { diffuse 0.9 phong 1}
        } // end of texture
 translate<0,0.4,0>
 } // end Round_Box
}  //--------------------- end of Chassis
#end // ---------------------------------

object{ Chassis( 30 )
        rotate<0,0,0>
        translate<0,0,0>}