Elica

Come fare una elica
con un numero variabile di pale.

Una Elica con un Numero variabile di Pale.
Per mantenere questa costruzione così flessibile come possibile l'angolo di rotazione dell'elica é dichiarato al inizio del seguente.
Per animazioni si può cambiare questa dichiarazione per es. così: "#declare Rotation_Angle = 360*clock;" Con "Number_of_Blades" e la lunghezza delle pale "Blade_Radius", adattare le dimensioni dell'elica é molto facile.

Le pale dell'elica

#declare Rotation_Angle =  20;
// ------------------------------------ dimensions of the blades
#declare Number_of_Blades = 5;
#declare Blade_Radius  = 3.00; // length of the propeller blades
// --------------------------------------- texture of the blades
#declare Blades_Texture =
 texture { Chrome_Metal finish{ambient 0.1 diffuse 0.8 phong 1}}
// -------------------------------------------------------------
union{  // propeller -------------------------------------------
   cylinder  { <0,0,-0.01>,<0,0,1.00>,0.10 }  // propeller axis
   difference{                                 // propeller nose
               sphere{<0,0,0>, 1}
               box {<-1,-1,-0.1>,<1,1,1>}
               scale <1,1,2.5>*0.3
               translate<0,0,0.2>
             }
   union{  // blades
     #declare Nr = 0;
     #declare End = Number_of_Blades;
     #while (  Nr < End)
        sphere { < 0, 0, 0>,0.5
                 translate <0.5,0,0>
                 scale <1,0.15,0.04> rotate <10,0,0>
                 scale Blade_Radius
                 texture {Blades_Texture}
                 rotate< 0,0, 360/End * Nr >
               }
     #declare Nr = Nr + 1;
     #end
   } // end of union of the blades
   texture{Blades_Texture}
   translate <0,0,-0.5>
   rotate <0,0,Rotation_Angle>
} // end of union propeller  ------------------------------------