Eine abrollende Kette
Animation einer Rollenkette
Wie man eine rollende Kette, wie etwa eine Fahrrad- oder Motorradkette,
einen Keilriemen, eine Gleiskette oder ein Förderband animiert.

Wie animiert man eine Rollenkette?
Zunächst sollte man die Geometrie zweier Kreise mit ihren externen Tangenten verstehen.
Betreffs genaueren Informationen siehe hier:
Externe Tangenten zweier Kreise
Bei gegebenen Radien r₁ > r₂ und der Achsentfernung d
mit r_i = r₂-r₁ erhalten wir für den Kettenring:
Die Länge der linearen Teile: 2·t = 2·sqrt( d² - r_i²).
Der Winkel der Kette: α = asin(r_i/d).
Das Segment des Kreises 1: l₁ = 2π·r₁ ·(180+2·α)/360.
Das Segment des Kreises 2: l₂ = 2π·r₂ ·(180-2·α)/360.

Zur äquidistanten Platzierung der Kettenglieder auf auf der Umfangslinie der Kette müssen wir die Länge der kompletten Kette durch die Anzahl der Kettenglieder dividieren (Bei Fahrradketten gibt es 2 verschiedene Arten von Gliedern, daher muß hier eine gerade Anzahl verwendet werden!).

Zur Animation einer rollenden Kette müssen wir die Kettenglieder auf 4 unterschiedlichen Teilen des Umfangs auf 4 verschiedene Arten platzieren, abhängig von der aktuellen Position des Kettengliedes! Dies können wir mittels der bedingten Anweisung mit '#if' erreichen:

// -------------- dimensions -----------
#local R1 = 0.15;  // big wheel radius
#local R2 = 0.075; // small wheel radius
#local Dist = 0.30;// axis distance
#local Link_N = 30;// number of links
// -------------- calculations ---------
#local Ri = R1-R2;
#local C_Angle = degrees(asin(Ri/Dist));
// chain linear length
#local LLen=sqrt(pow(Dist,2)-pow(Ri,2));
// segment angle and length
#local Ang1 = 180+2*C_Angle;
#local Ang2 = 180-2*C_Angle;
#local Len1 = Ang1/360*2*pi*R1;
#local Len2 = Ang2/360*2*pi*R2;
// total length
#local C_Len = 2*LLen+Len1+Len2;
#local Link_L  = C_Len / Link_N;
#declare Link =        // the chain link
sphere{<0,0,0>,0.0075
       texture{Chrome_Metal}}
//--------------------------------------
#local Ani=clock*Link_Len;// animation!
union{ //-------------------------------
#local Nr = 0; // start loop
#while (Nr < Link_N)
 #local Pos = mod(Nr*Link_L+Ani,C_Len);
 //-------------------------------------
 #if(Pos< Len1 ) // front down
  #local Rot1 = Pos/Len1*Ang1;
  object{Link translate<0,R1,0>
         rotate<0,0,-Rot1 +C_Angle>}
 #end //--------------------------------
 #if((Pos>Len1) & (Pos<=Len1+LLen))
  #local LPos = Pos-Len1; // base side
  object{Link translate<-LPos,-R1,0>
            rotate<0,0,-C_Angle>}
 #end //--------------------------------
 #if((Pos>Len1+LLen )       // back up
      & (Pos<= Len1+LLen+Len2))
  #local Rot2 =
      (Pos-Len1-LLen)/Len2*Ang2;
  object{Link translate<0,R2,0>
          rotate<0,0,-Rot2-C_Angle-180>
              translate<-Dist,0,0>}
 #end //--------------------------------
 #if((Pos>Len1+LLen+Len2) // up forward
      & (Pos <= Len1+LLen+Len2+LLen))
  #local LPos = Pos-(Len1+LLen+Len2);
  object{Link translate<LPos,R2,0>
              rotate<0,0,C_Angle>
              translate<-Dist,0,0>}
 #end //--------------------------------
#local Nr = Nr + 1;  // next Nr
#end // --------------- end of loop
} // end of union ----------------------

Die Geometrie zweier Kreise mit externen Tangenten!

Die Positionen der Kettenglieder einer Rollenkette.

Animierte Positionen für die Glieder einer Rollenkette!

Szenenbeschreibung
für POV-Ray:
"Roller_Chain_1.ini" und
"Roller_Chain_1.pov"

Eine andere animierte Rollenkette

Weiter mit zwei verschiedenen Arten von Kettengliedern hier:
Fahrradkette.
Betreffs Animationen von rollenden Fahrradketten siehe hier:
3D-Animations - Engineering.

top

Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller 3D Animationen mit POV-Ray Grundlagen und Beispiele zu Animationen.

Eine abrollende Kette Animation einer Rollenkette Wie man eine rollende Kette, wie etwa eine Fahrrad- oder Motorradkette, einen Keilriemen, eine Gleiskette oder ein Förderband animiert.

Szenenbeschreibung für POV-Ray: "Roller_Chain_1.ini" und "Roller_Chain_1.pov"

Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller

3D Animationen mit POV-Ray
Grundlagen und Beispiele zu Animationen.

Eine abrollende Kette
Animation einer Rollenkette
Wie man eine rollende Kette, wie etwa eine Fahrrad- oder Motorradkette,
einen Keilriemen, eine Gleiskette oder ein Förderband animiert.

Szenenbeschreibung
für POV-Ray:
"Roller_Chain_1.ini" und
"Roller_Chain_1.pov"