Descrizioni ed esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
Design del Interno dei Oggetti trasparenti con POV-Ray
English English English
Français français
Deutsch Deutsch

Home
- Tutoriels POV-Ray


  Indice del contenuto
  material, interior, media

  - Sintassi di material,
      texture e interior
  - Vetro della finestra
        e max_trace_level
  - fog - Nebia
  Media
  - Sintassi di media
  - Media e Density Maps
  Atmospheric Media
    con/senza density map
  - Raggi nella Nebbia
  Object Media
  Emitting Media
  - Spada di Luce
  - Fiamme di candele
  Scattering Media
  - Luce della Finestra
  - Vapore, Fumo, Nuvole
  Absorbing Media
  - Tromba d'Aria.
  Problemi Speciali con Media
  - Cambiare la scala di Media
  - Sovrapposizione di Media
                                             

"media" e "density maps"      

Ci sono 4 typi di modelli (pattern) che sono specialmente interessante con media density maps:
spherical
sphere{
    <0,0,0>, 1
    pigment{rgbt 1}
    hollow
 interior{ //-----------
 media{
  emission <1,1,1>
  scattering{1,<1,1,1>}
  density{ spherical
    turbulence 0
    color_map {
     [0 rgb 0.0]//border
     [1 rgb 1.0]//center
     } // fin color_map
   } // fin density
  } // fin media ---
 } // fin interior
 translate <0,1.00,0>
} //----- end of sphere
cylindrical
cylinder{
   <0,-0.5,01>,<0,1,0>,1
   pigment{rgbt 1}
   hollow
 interior{ //-----------
 media{
  emission<-.5,-.5,1>*.6
  scattering{1,<1,1,1>}
  density{ cylindrical
    turbulence 0
    color_map {
     [0 rgb 0.0]//border
     [1 rgb 1.0]//center
     } // fin color_map
   } // fin density
  } // fin media ----
 } // fin interior
 translate <0,1,0>
} //---- end of cylinder
boxed
box{
    <-1,-.5,-1>,<1,1,1>
    pigment{rgbt 1}
    hollow
 interior{ //-----------
 media{
  emission<-.2,1,-.5>*.6
  scattering{1,<1,1,1>}
  density{ boxed
    turbulence 0
    color_map {
     [0 rgb 0.0]//border
     [1 rgb 1.0]//center
     } // fin color_map
   } // fin density
  } // fin media ----
 } // fin interior
 translate <0,1,0>
} //------- end of box
planar
box{
    <-1,-.25,-1>,<1,1,1>
    pigment{rgbt 1}
    hollow
 interior{ //-----------
 media{
  emission<1,-.25,1>*.6
  scattering{1,<1,1,1>}
  density{ planar
    frequency 5
    color_map {
     [0 rgb 0.0]//border
     [1 rgb 1.0]//center
     } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior
 translate <0,1,0>
} //------- end of box

Certament possono anche usare tutti i modelli con modificzioni che sapiamo delle testure., Qui 3 altri esempi:
bozo
box{ <-1,-0.5,-1>,<1,1,1>
    pigment{ rgbt 1 }
    hollow
 interior{ //-----------
 media{
  emission <-0.4,0.7,1>*0.6
  scattering{ 1, <1,1,1>
              extinction  1.2 }
  density{ bozo
    turbulence 0
    frequency 20
    color_map {
     [0.0 rgb 0.0]//border
     [0.5 rgb 0.1]
     [1.0 rgb 1.0]//center
     } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior
 translate <0,1,0>
} //------- end of box
gradient x
box{ <-1,-0.5,-1>,<1,1,1>
    pigment{ rgbt 1 }
    hollow
 interior{ //-----------
 media{
  emission <1,0.2,-0.6>*0.9
  scattering{ 1, <1,1,1>
              extinction  2.0 }
  density{ gradient x
    turbulence 0.5
    frequency 4
    color_map {
     [0.0 rgb 0.0]//border
     [0.5 rgb 0.1]
     [1.0 rgb 1.0]//center
     } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior
 translate <0,1,0>
} //------- end of box
quilted
box{ <-1,-0.5,-1>,<1,1,1>
    pigment{ rgbt 1 }
    hollow
 interior{ //-----------
 media{
  emission <1,-0.8,-0.6>*1.0
  scattering{ 1, <1,1,1>
              extinction  2.5 }
  density{ quilted
    turbulence 0.0
    frequency 6
    color_map {
     [0.0 rgb 0.0]//border
     [0.5 rgb 0.1]
     [1.0 rgb 1.0]//center
     } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior
 translate <0,1,0>
} //------- end of box

Sopra Density Maps e Oggetti di Container. .
Se usiamo " density " con "turbulence", sarrebbe buono ingrandire l'oggetto di container!

Una sfera con raggio 1.
"Density map" senza "turbulence".
 
Una sfera con raggio 1.
"Density map" con "turbulence 1.3".
Sfera container taglia "density"!
Una sfera con raggio 1.5.
"Density map" con "turbulence 1.3".
"Density" nella sfera di container !

Possiamo anche tenere "density" con "turbulence" nel interno di una sfera con la periferia tenue
con "intersection" di una "density" con una altra!

Una sfera con raggio 1.
"Density map" senza "turbulence".
 
Una sfera con raggio 1.5.
"Density map" con "turbulence 1.3".
Container ingrandito per "density"!
Una sfera con raggio 1.
"Density map" con "turbulence 1.3"
Aggiunto "density" senza turbulence.
La periferia tenue nel container!

Algebra Booleana con media - operazioni logici con "media" e "density maps"
È possibile di usare più che una "density map" ma anche usare più che una "media". Le regole e i resultati sono lo stesse come con la CSG con solidi.

intersection                       union                                      
 media{ ...
   density{ ... } //1
   density{ ... }//2
 } // end media


 
 media{ ...  //1
   density{ ... }
 } // end media 1
 media{ ...  //2
   density{ ... }
 }// end media 2
 
top
© Friedrich A. Lohmüller, 2009
http://www.f-lohmueller.de