Home
- Tutoriels POV-Ray
Indice del contenuto
material, interior, media
- Sintassi di material,
texture e interior
- Vetro della finestra
e max_trace_level
- fog - Nebia
Media
- Sintassi di media
- Media e Density Maps
Atmospheric Media
con/senza density map
- Raggi nella Nebbia
Object Media
Emitting Media
- Spada di Luce
- Fiamme di candele
Scattering Media
- Luce della Finestra
- Vapore, Fumo, Nuvole
Absorbing Media
- Tromba d'Aria.
Problemi Speciali con Media
- Cambiare la scala di Media
- Sovrapposizione di Media
|
Cambiare la scala con "object media"
|
|
Scaling "object media"
Se aumentiamo la scala di un "object media" in una scena di POV-Ray
la media density non si cambia conformemente!
Di conseguenza i raggi vanno attraverso di più di media e questo fa un effetto più forte!
Per es. un scattering media ha una diffusione più intensa e per questo raggione
sembra più buio
(per es.: i'immagine seconda su questa paggina!).
Come si cambiare la scala
di "object media" correttamente:
Per avere un effetto costante dobbiamo ridurre il
colore (per es. per scattering) con dividere il colore con il fattore di scale!
|
Object media in scale 1.
|
Object media in scale 4.
|
Object media in scale 4 with color divided by 4.
|
|
Esempio: Come cambiare la scala di media
#declare Cloud_Scale = 10;// 1, ... 500
#declare Cloud =
sphere{ <0,0,0>, 1
pigment{rgbt 1}
hollow
interior{ //-----------
media{
emission <1,1,1>/Cloud_Scale
scattering{ 1,<1,1,1>/Cloud_Scale}
density{
spherical
turbulence 0
color_map {
[0 rgb 0.0]//border
[1 rgb 1.0]//center
} // end color_map
} // end of density
} // end of media ---
} // end of interior
scale Cloud_Scale
} //----- end of sphere
//--------------------------------------
object{ Cloud
// don't do any additional scaling here!
translate<0,1,15>
} //--------------------------------------
|
E come un oggetto macro:
|
Object media con Cloud_Scale 1 a <0,1,1>
Object media con Cloud_Scale 10 a <0,1,15>
Object media con Cloud_Scale 500 a <0,50,600>
|
|
Esempio: Una nuvola con media come macro
#macro Cloud_01( Cloud_Scale )
sphere{ <0,0,0>, 1
pigment{rgbt 1}
hollow
interior{ //-----------
media{
emission <1,1,1>*0.75/Cloud_Scale
scattering{ 1,<1,1,1>*5/Cloud_Scale}
samples 20 // increase = more precise
intervals 1
density{ spherical
scale 0.65
turbulence 1.00
color_map {
[0 rgb 0.0] // border
[1 rgb 1.0] // center
} // end color_map
} // end of density
} // end of media ---
} // end of interior
scale Cloud_Scale
} //----- end of sphere
#end // end of macro ---------------------
object{ Cloud_01( 5 )//Cloud(Cloud_Scale)
// don't do any additional scaling here!
rotate <0,0,0>
translate <0,4,5>
} //--------------------------------------
|
|
Object media Cloud_1, scale 5 a <0,4,5>
|
|
