Motivi regulari:
   checker, hexagon, square, triangular

checker = motivo a scacchiera. (lunghezza originale di un quadrato = 1) Esempio: pigment{ checker // 2 colori/testure color White color Black }

hexagon = piastrelle tipo esagono Esempio: pigment{ hexagon // 3 colori/testure color Red color Yellow color Orange }

square - colori in quadrati - Nuovo con POV-Ray 3.7 (lunghezza originale di un quadrato = 1) Esempio: pigment{ square //max.4 colori/testure color White color rgb<1.00, 0.00, 0.30>, color rgb<0.10, 0.70, 0.00>, color Orange }

triangular - colori in triangoli - Nuovo con POV-Ray 3.7 (lunghezza originale di un lato di base = 1) Esempio: pigment{ triangular //max.6 colori/testure color Red, color rgb<1.0, 0.4, 0.0>, color rgb<1.0, 0.9, 0.0>, color rgb<0.5, 1.0, 0.0>, color rgb<0.5, 0.5, 1.0>, color rgb<0.5, 0.0, 1.0>}

Esempi per checker e hexagon:

//--------------------- checker con colori -----------------
plane{<0,1,0>,0
      texture{
              pigment{checker
                      color White color rgb<0.8,0.65,0.8>
                      scale 0.5}
              finish { diffuse 0.4 reflection 0.5}
             }// end of texture
        }

//---------------------hexagon con colori ------------------
sphere {<0,0,0>,0.8 translate<0.5,1,1>
        texture {pigment{hexagon  // a bisogno di 3 colore!
                         color rgb<1,0.85,0.1>
                         color rgb<1,0.95,0.5>
                         color rgb<0.7,0.3,0.5>
                         rotate<90,-50,0> scale 0.2
                         } // end of pigment
                 normal { wrinkles 0.75 scale 0.025 }
                 finish { diffuse 0.9 specular 0.2}
                } //end of texture
       translate<-0.7,2.25,-1.2>
      } //end of sphere

//--------------------- hexagon con testure ----------------
sphere {<0,0,0>,0.8
    texture {
      hexagon // a bisogno di 3 testure!
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       normal { crackle 0.5 scale 0.05 }
       finish { diffuse 0.9 specular 0.2}
              }// end of 1st texture
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       finish { diffuse 0.9 specular 0.2}
              }// end of 2nd texture
      texture {
       Polished_Chrome //replace Chrome color by:
       pigment{ color rgb<1,0.75,0>}
       normal { bumps 0.5 scale 0.15 }
       finish { diffuse 0.9 }
              }// end of 3rd texture
      scale 0.2 rotate<110,-50,0>
     }// ---------------------------end of texture
  translate<-0.7,2.25,-1.2>
 }//--------------------------- end of sphere ---------

//-------------- Rainbow Stripes Sphere --------------------
sphere {<0,0,0>,2 scale<1,0.5,1>
        texture {pigment{ radial frequency 15}
                 finish { diffuse 0.9 specular 0.7}
                }// end of texture
        translate<0,1.5,2>}