#declare Pattern_Object_1=
union{
 box{<-7.00,1.35,-1.50>,< 0.78,1.40,1.5>}
 box{<-7.00,1.25,-1.50>,< 0.78,1.30,1.5>}
 text{ ttf "arialbd.ttf","POV-Ray",0.5,0
        matrix<1, 0, 0, //  shear_y_to_x
            0.35, 1, 0,
               0, 0, 1,
               0, 0, 0>
        scale<0.83,0.9,1>
        translate<-5.7,1.6,-1.5>}
 text{ ttf "arialbd.ttf","POV-Ray",0.5,0
        matrix<1, 0, 0, // shear_y_to_x
            0.35, 1, 0,
               0, 0, 1,
               0, 0, 0>
        rotate<0,180,0>
        scale<0.83,0.9,1>
        translate<-2.25,1.6,1.5>}
} // end of union
//---------------------------------------
#declare Object_Pigment_1 =
pigment{
   object {
       Pattern_Object_1
       color rgb<1,0.95,0.75> // outside
       color rgb<0.8,0.15,0>  // inside
      }// object
  } // end pigment
//---------------------------------------
#declare Truck_Texture =
   texture{ pigment{ Object_Pigment_1 }
            finish { phong 1 }
          }
//---------------------------------------
#include "Truck_12.inc"
//---------------------------------------
object{ Truck_12(
           0,// Front wheel angle: ~+/-60
           Truck_Texture
         ) //----------------------------
        scale< 1,1,1>
      //  rotate<0,180,0>
      //  translate<-5.00,0,0.00>
      } //-------------------------------