|
|
"color_map { ... }" - tableaus de couleurs pour motifs
|
Un "color_map { ... }"
est un tableau de couleurs, que range le couleurs aux nombres entre 0.00 et 1.00.
Ces tableaux de couleurs on peut utiliser avec des motifs diverses.
Le motif plus facile est le motiv gradient:
pigment{
gradient <0,1,0>
color_map {[0.0 color rgb<1,1,1>] // White
[0.5 color rgb<1,0,0.2>] // red wine
[1.0 color rgb<1,1,1>] // White
} // end of color_map
} // end of pigment
|
|
|
Le motif se est répété dans une altitude de 1 unité.
Si nous voulons faire le motif plus petit ou plus grand, nous pouvons ajuter après
(ou devant!) le commande color_map quelche chose comme "scale 0.25"
au "pigment".
Comme cela on peut aussi tourner ("rotate") et déplacer ("translate") le motif!
pigment{
gradient <0,1,0>
color_map {[0.0 color rgb<1,1,1>] // White
[0.5 color rgb<1,0,0.2>] // red wine
[1.0 color rgb<1,1,1>] // White
} // end of color_map
scale 0.25
} // end of pigment
|
|
|
Quelques exemples de color_map
avec de motifs (voyez aussi: Listes de Motifs)
|
gradient <0,1,0> turbulence 1.0
|
bozo
|
crackle
|
Changer de l'une couleur à l'autre
- mélange douce ou délimité nettement :
Se on veut un changement délimité nettement des couleurs on doit répérér les couleurs
aux lignes de la frontière :
gradient <0,1,0>
color_map {[0.0 color White]
[0.5 color White]
[0.5 color Red ] // précis
[1.0 color Red ] } |
|
Melanger délimité nettement et douce est possible aussi:
gradient <0,1,0>
color_map {[0.0 color White]
[0.3 color White] // dur
[0.3 color Red ]
[1.0 color White] } // douce à blanc au débu |
|
gradient <0,1,0>
color_map {[0.0 color White]
[0.5 color Red ] // douce
[1.0 color White] } // douce à blanc au débu |
|
sphere{<0,0,0>,1
texture{pigment{gradient <0,1,0> //
color_map{[0.0 color Blue ]
[0.2 color Navy ]
[0.5 color White]
[0.8 color Navy ]
[1.0 color Blue ]
}// end of color_map
scale 2 translate<0,-1,0>
}// end of pigment
finish{ diffuse 0.9 phong 1.0 }
}// end of texture
scale <1.3,0.75,1.3> translate<0,1.2,-0.3>
}// end of sphere |
Pour un sphère de ciel bleu avec un diamètre de 10000 unités et une couleur
que se fond de blanc à l'horizon vers bleu au zénith,
on peut utiliser une sphère avec le » color_map « ci-dessus
avec une èchelle » scale 10000 « --
Ici nous devrons ajouter un » finish { ambient 1 diffuse 0} «
pour le ciel ne reçoit aucune ombre (que j'espère bien! :-)
sphere{ <0,0,0>, 1
texture{
pigment{
gradient <0,1,0>
color_map{[0.0 color White]
[1.0 color Blue ]
}
} // end of pigment
finish{ ambient 1 diffuse 0 }
}// end of texture
scale 10000
}// end of sphere |
Exemple de "color_map{...}":
sphere{ <0,0,0> , 1
texture{
pigment{ crackle
scale 1.5 turbulence 0.35
color_map{
[0.04 color Black]
[0.08 color Black]
[0.32 color rgb<1,0.65,0>]
[1.00 color rgb<1,1.0,0.5>]
} // end of color_map
scale 0.2
} // end of pigment
normal { bumps 0.75 scale 0.02}
finish { diffuse 0.9 phong 1}
rotate<0,-30,0>
translate<0.01, 0.04, 0.00>
} // end of texture -----------------------
scale<1,1,1> rotate<0,0,0>
translate<0.40,1, 0.25>
} // end of sphere ------------------------------- |
|
